Formated by GeSHi
//Scripted by c-x@email.cz
//Jabber: c-x@jabber.org
//poznamky: Node 540 je potrba dodelat, ceka se na dodelani Poockeho. Caduca na radku asi 300 nemuze byt pouzitelna..
 
#include "..\headers\define.h"
#include "..\headers\command.h"
#include "..\headers\ModReact.h"
#include "..\headers\Party.h"
 
#define NAME          SCRIPT_BADSTRAZ
#define TOWN_REP_VAR    GVAR_TOWN_REP_BAD_WATERS
 
procedure start;
procedure timed_event_p_proc;
procedure critter_p_proc;
procedure pickup_p_proc;
procedure talk_p_proc;
procedure look_at_p_proc;
procedure description_p_proc;
procedure use_skill_on_p_proc;
procedure destroy_p_proc;
procedure damage_p_proc;
procedure map_enter_p_proc;
procedure Node998;
procedure Node999;
procedure Floats;
procedure look_at_p_proc;
procedure description_p_proc;
procedure talk_p_proc;
procedure Node500;
procedure Node510;
procedure Node520;
procedure Node530;
procedure Node540;
procedure Node550;
procedure ss555;
procedure Node600;
procedure Node610;
procedure ss611;
procedure Node620;
procedure Node630;
procedure Node640;
procedure Node650;
procedure Node700;
procedure ssPodlejzak;
 
 
 
/* Local Variables which are saved. All Local Variables need to be
   prepended by LVAR_ */
#define LVAR_Flags      (0)
#define LVAR_Home_tile  (1)
 
#define NUM_WARN      	2
#define PARAM		      2
#define DISTANCE        5
#define TIME_MIN        25
#define TIME_MAX        60
 
#define LVAR_herebeforeNumbers (2)
#define LVAR_Podlejzak (3)
variable pickupWarning;
 
 
 
//----------------------------------------------------------------------------
 
procedure start
begin
   flush_add_timer_event(self_obj, FLOAT_SPEED_NORMAL, 1);
   flush_add_timer_event(self_obj, game_ticks(random(TIME_MIN, TIME_MAX)), PARAM);
end
 
//----------------------------------------------------------------------------
 
procedure timed_event_p_proc
begin
   variable tmp_pos;
 
   if fixed_param == 1 and not combat_is_initialized then
   begin
      call Floats;
      flush_add_timer_event(self_obj, FLOAT_SPEED_NORMAL, 1);
   end
 
   random_moving(PARAM, DISTANCE, TIME_MIN, TIME_MAX)
end
 
//----------------------------------------------------------------------------
 
procedure critter_p_proc
begin
   if hostile and self_can_see_dude then
      self_attack_dude;
end
 
//----------------------------------------------------------------------------
 
procedure pickup_p_proc
begin
 
end
 
//----------------------------------------------------------------------------
 
 
procedure use_skill_on_p_proc
begin
 
end
 
//----------------------------------------------------------------------------
 
procedure destroy_p_proc
begin
   inc_good_critter
end
 
//----------------------------------------------------------------------------
 
procedure damage_p_proc
begin
   set_hostile;
end
 
//----------------------------------------------------------------------------
 
procedure map_enter_p_proc
begin
   if (local_var(LVAR_Home_tile) == 0) then 
   begin
      set_local_var(LVAR_Home_tile, self_tile);
   end
end
 
 
 
 
 
procedure Node998
begin
   set_hostile;
end
 
procedure Node999
begin
end
 
 
procedure Floats
begin
   floater_rand(200,214);
 
// {200}{}{Veška, bleška, myška, šváb. Nic z toho neprojde.}
// {201}{}{Konspiráce! Konsipráce!}
// {202}{}{NAŠÍ BRANOU ČÍNSKÝ AGENT NEPROJDE!}
// {203}{}{MÝMI DVEŘMI KOMUNISTICKÝ AGENT NEPROJDE!}
// {204}{}{Kdepak, nehnu se odtud, ani kdybych se měl pokadit.}
// {205}{}{Šajze, šajze!! Asi ztrácím svou rodnou němčinu.}
// {206}{}{A maj teda ti Číňani vůbec koule?}
// {207}{}{Dávám bolševismu rok.}
// {208}{}{'sic!}
// {209}{}{Co to ksakru ten Lorne navečír chytil... A CO TO TEĎ U NÁS SEBASTIAN PITVÁ!}
// {210}{}{Dlouhý život demokracii!}
// {211}{}{Ještě jedna podělaná hlídka přímo pod sirénama a moje poslední ucho půjde do hajzlu.}
// {212}{}{Tak dlouho bude DeHavillant s krčiskama chodit, až se mu ten pytel utrhne.}
// {213}{}{Rád bych byl dneska na šichtě povídavější, ale byl jsem nenávratně ideologicky poškozen čínským popem.}
// {214}{}{Není boha, abychom ty Číňany neporazili alespoň v hokeji.}
end
 
procedure look_at_p_proc
begin
   script_overrides;
 
   display_msg(mstr(random(100,103)));
 
// {100}{}{Ghoul typu armádní očko.}
// {101}{}{Ghoulík na číhané na hezouny.}
// {102}{}{Dosti zapáchající a hubatý ghůl.}
// {103}{}{Hlídač, kterého jen tak nezkorumpuješ.}
end
 
procedure description_p_proc
begin
   script_overrides;
 
   display_msg(mstr(random(110,113)));
 
// {110}{}{Je to celkem blbost, ale vypadá spokojeně. Pozor, ať se taky nenakazíš.}
// {111}{}{Vypadá, že by střežil i něčí hovno, kdyby mu to přišlo ideologicky správné.}
// {112}{}{Říká se, že všichni vymývači mozků na světě těží z existence znuděných průměráků bez životního smyslu. Tenhle ghoulík dané paradigma určitě nesvrhne.}
// {113}{}{Jistě si nepřeje, aby mu unikla byť jen myška, ale nedá to hajzlík znát.}
end
 
 
 
 
procedure talk_p_proc
begin
   /*Evil_Critter:=0;
   Slavery_Tolerant:=SLAVE_TOLERANT;
   Karma_Perception:=KARMA_PERCEPTION1;
 
   CheckKarma;
 
   GetReaction; */
 
   start_gdialog(NAME,self_obj,4,-1,-1);
   gSay_Start;
 
      if town_rep >= 10 then
         begin
            if local_var(LVAR_Podlejzak) == 1 then
               call Node520;
            else
               call Node550;
         end
 
      else if local_var(LVAR_herebeforeNumbers) == 0 then
         begin
            inc_local_var(LVAR_herebeforeNumbers, 1);
            if party_size >= 3 then
               begin
                  call Node530;
               end
            else
               call Node500;
         end
 
      else if local_var(LVAR_herebeforeNumbers) == 1 then
         begin
            inc_local_var(LVAR_herebeforeNumbers, 1);
            call Node510;
         end
 
      else if local_var(LVAR_herebeforeNumbers) >= 2 then
         begin
            inc_local_var(LVAR_herebeforeNumbers, 1);
            call Node520;
         end
 
   gSay_End;
   end_dialogue;
end
 
procedure Node500
begin
   // {500}{}{Musím tě požádat, abys odtud okamžitě odešel. Vidina tvého nekontrolovaného pobíhání za tímto plotem je pro jisté kapacity poněkud... "nežádoucí".}
   Reply(mstr(500));
 
   // {501}{}{Za plotem, copak je asi za plotem, pampadampam...} #N 600
   NOption(501,Node600,004);
   // {502}{}{Moment! Jsi ošklivý. Proč jsi tak ošklivý?} #N 700
   NOption(502,Node700,004);
   // {503}{}{Co, co! Uděláš mě?} #N610
   NOption(503,Node610,004);
 
   if (dude_is_stupid)then
      begin
         // {504}{}{Ty ale nebýt moje táta, ty nerozkazovala!} #N630; IDIOT PC
         NOption(504,Node630,001);
      end
 
   // {505}{}{Uf, no samozřejmě. Odsať pocať s těmi hezouny, viď?} #EXIT
   NOption(505,Node999,004);
end
 
procedure Node510
begin
   // {510}{}{Záležitosti za tímto plotem v žádném případě nejsou tvůj byznys, ty mladá prdýlko. Co se děje, NECHÁPEŠ TO? CHCEŠ TO SNAD GRAFICKY ZNÁZORNIT?}
   Reply(mstr(510));
 
   // {511}{}{Ano prosím.} #EXIT
   NOption(511,Node999,004);
   // {512}{}{Chraň Bůh!} #EXIT
   NOption(512,Node999,004);
end
 
procedure Node520
begin
   // {520}{}{Tady nemáš vůbec ale vůbec co čmuchat, hezoune. KOLIKRÁT TI TO ASI BUDEM MUSET JEŠTĚ ZOPAKOVAT, NEŽ NAŠE BOTY SKONČÍ VE VAŠICH ZADCÍCH?}
   Reply(mstr(520));
 
   // {521}{}{CO-KO-LIV.} #EXIT
   NOption(521,Node999,004);
   // {522}{}{Jak že to bylo? Vaše zadky v našich botkách? Erhm, nech to ležet...} #EXIT
   NOption(522,Node999,004);
end
 
procedure Node530
begin
   // {530}{}{V zájmu nás všech okamžitě odšpacírujte někam do pryč, OK? My tady turisty nemáme rádi.}
   Reply(mstr(530));
 
   // {531}{}{Za plotem, copak je asi za plotem, pampadampam...} #N600
   NOption(531,Node600,004);
   // {532}{}{Co, co! Uděláš mě?} #N610
   NOption(532,Node610,004);
 
   if dude_conversant >= 80 and Berenica_In_Party then
   //if dude_conversant >= 80 and Berenica_In_Party or Caduca_In_Party then //az bude Caduca v parte
      begin
         // {533}{}{Ale kamaráde, nějak se přece dohodnem. Za trochu blyštivých šutříčků, ohnivé vody, horkých avšak vlídných klínů tady jedné z mých kolegyň, a tak...} #N620; ŘEČ 80+, BERENICA NEBO CADUCA V PARTĚ
         NOption(533,Node620,004);
      end
 
   if (dude_is_stupid)then
      begin   
         // {534}{}{Ty ale nebýt moje táta. Ty nerozkazovala!} #N630; IDIOT PC
         NOption(534,Node630,001);
      end
 
   // {535}{}{No toto! Už se klidím svinským krokem.} #EXIT
   NOption(535,Node999,004);
end
 
procedure Node540
begin
   // {540}{}{Dělej si co chceš a kde chceš, hezoune. Našel sis cestu jak nás přechcat, takže jsi zároveň dost velký na to, aby ses v Bad Waters nenechal sežrat nějakou vysokou šarží. My tě nevidíme - čau.}
   Reply(mstr(540));
 
   // {541}{}{Ale já jsem přímo TADY!} #EXIT
   NOption(541,Node999,004);
 
   if (dude_conversant) >= 60 then
       begin
         // {542}{}{Tak to mě vyšlo levně, dík.} #EXIT; ŘEČ 60+
         NOption(542,Node999,004);
      end
end
 
procedure Node550
begin
   // {550}{}{Nazdar hezo... HERONAME! Nabumbáme se někdy spolu v Avro Baru, co řikáš?}
   Reply(mstr(550 + dude_name + 5500));
   // {551}{}{Říkám, že chovat se k lidem v Bad Waters může být prima!} #EXIT
   NOption(551,Node999,004);
   // {552}{}{Když to musí bejt...} #EXIT
   NOption(552,Node999,004);
   // {553}{}{Jdi ode mě, ty skřete! Nic jsi tu za těch šedesát sedmdesát let nedokázal. Já ano - a to jsem měl na to jen posraný letošní rok. Tomu se říká lekce z produktivity, kámo!} #EXIT; REPUTACE -1, PŘÍŠTĚ DEGRADACE BUĎ NA #N 520 NEBO #N 530, PODLE TOHO, CO BYLO ZATÍM NEJVÝŠE POUŽITO
   NOption(553,ss555,004);
end
 
procedure ss555
begin
   inc_town_rep(-1);
   set_local_var(LVAR_Podlejzak, 1);
   call node999;
end
 
 
 
 
 
procedure Node600
begin
   // {600}{}{Bláhový chlapče! Ty to dočista nechápeš. To je úplně jedno, co tam je nebo co tam není. Ani nás to nezajímá. Jediné, co nás zajímá, seš TY pěkně za TOUHLE čarou. Hezkej den.}
   Reply(mstr(600));
 
   // {601}{}{Uděláš mě?} #N610
   NOption(601,Node610,004);
   // {602}{}{Jako obvykle mě těšilo.} #EXIT
   NOption(602,Node999,004);
end
 
procedure Node610
begin
   // {610}{}{To ne, proč? Ale palposty značky Rozšmelcovač bezpochyby ano. Nebuď hloupější, než je třeba, paskudná tvářičko. Nesnaž se krájet tupou stranou nože, když to není nutné. Chápem se?}
   Reply(mstr(610));
 
   // {611}{}{Vyhlašuju válku tvý prdeli, tady a teď. Ay caramba!} #WAR; KARMA -5, BW REPUTACE GOES TO -30
   NOption(611,ss611,004);
   // {612}{}{Věžička značky roz-cožeto? Vždyť je to úplný zďorbo... uf, tedy možná.} #EXIT
   NOption(612,Node999,004);
end
 
procedure ss611
begin
   inc_general_rep(-5);
   inc_town_rep(-30);
   set_hostile;   
end
 
procedure Node620
begin
   // {621}{}{Ne, my dva se zcela určitě na ničem nedohodneme. Obrana starých principů Ameriky si žádá žádné kompromisy, takže raději považuj celou záležitost za nedorozumění. Ty můj rozkošný šutříčku. Heh-heh.}
   Reply(mstr(621));
   // {622}{}{Teď mi asi beze srandy řekneš, že se mnou zameteš podlahu, ne?} #N610
   NOption(622,Node610,004);
   // {623}{}{Jak myslíš. [Fňuky fňuk] Mě to přišlo jako celkem férovej kšeft.} #EXIT
   NOption(623,Node999,004);
end
 
procedure Node630
begin
   // {630}{}{[Tento ghůl je očividně překvapen - není divu - a čumí] Máš z prdele štěstí, hezoune blboune, že tě momentálně nemá kdo v zájmu této základny vyvést.}
   Reply(mstr(630));
 
   // {631}{}{To jednou, když HERONAME mít nápad briliantní že hovno brahmíní strčit si v pusa, táta mě vzít a naplácat mi na prdel holá. Před hodně člověků. Sedum den a sedum večer mě pak bolet prdel i kouličky.} #N640
   NOption(631 + dude_name + 6310,Node640,004);
end
 
procedure Node640
begin
   // {640}{}{[Civí a taky začíná nějak divně vrzat]}
   Reply(mstr(640));
 
   // {641}{}{Tak. Příhoda vtipná, chtít dobrota. Dobrota je cena za příhoda vtipná.} #N650
   NOption(641,Node650,004);
end
 
procedure Node650
begin
   // {650}{}{Drž zobák, nebo tě vážně nasekám na dobrotu!}
   Reply(mstr(650));
 
   // {651}{}{Cháchá, dělám legraci. Chovat se ty málo společensky.} #EXIT
   NOption(651,Node999,004);
   // {652}{}{Vžžžžm-frrrr-uííí-kak!} #EXIT
   NOption(652,Node999,004);
end
 
procedure Node700
begin
   // {700}{}{CO? Jsem jeden z nejpřitažlivějších ghoulů. To odvoláš!}
   Reply(mstr(700));
 
   set_local_var(LVAR_Podlejzak, 1);
 
   if dude_conversant >= 80 then
      begin
         // {701}{}{Ale notak, nic si tu přede mnou nenamlouvej. Nedá se to popsat ani jako vítěztví jednookýho mezi slepejma. Nene. Věc se má tak, že JÁ jsem krásný, kdežto ty, ty jsi jen taková srandovní atrakce pro krásný a slušný lidi...} #WAR; ŘEČ 80+, KARMA -5, BW REPUTACE GOTO -30
         NOption(701,ss611,004);
      end
 
   if dude_conversant >= 80 and Zed_In_Party then
      begin
         // {702}{}{Blázníš, chlape? Mít psa, vsadím tadyhle Zeda, že by se tě bál vobčuchat.} #WAR; ŘEČ 60+, KARMA -5, BW REPUTACE GOTO -30, ZED V PARTĚ
         NOption(701,ss611,004);
      end
 
   // {703}{}{Jasně, jasně! Zapomeň na to, chci pro dnešek ze života vyváznout živý.} #EXIT; BW REPUTACE -2, PŘÍŠTĚ ROVNOU #N 520
   NOption(703,ssPodlejzak,004);
   // {704}{}{Ehhh, jistěže. Chtěl jsem říct... specifický. Jo, to je to, co jsem chtěl říct. Jsi SPECIFICKÝ... A já jsem blbec, co by se měl co nejdřív odklidit. Notak, vem do zaječích...} #EXIT; BW REPUTACE -2, PŘÍŠTĚ ROVNOU #N 520
   NOption(704,ssPodlejzak,004);
end
 
 
 
procedure ssPodlejzak
begin
   inc_town_rep(-2);
   call Node999;
end
Parsed in 0.11441898 seconds